<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:glade="http://glade.gnome.org/glade-2.0.dtd"
        xmlns:regexp="http://exslt.org/regular-expressions"
        xmlns:str="http://exslt.org/strings"
        xmlns:sam="http://liddicott.com/sam"
        xmlns:func="http://exslt.org/functions"
        xmlns:valax="http://www.liddicott.com/valax"
        extension-element-prefixes="regexp str func sam valax"
        exclude-result-prefixes="regexp str func sam valax">
  <xsl:output method="text" indent="no" omit-xml-declaration="yes"/>
	
	<xsl:param name="class"/>
	<xsl:param name="class-prefix"/>
	<!-- these are more constants than params -->
  <xsl:param name="idchars">abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789_</xsl:param>
  <xsl:param name="eol" select="'&#xA;'"/>

  <func:function name="valax:identifier-char">
    <xsl:param name="char"/>
    <func:result select="translate($char,$idchars,'')=''"/>
  </func:function>

  <func:function name="valax:glade-to-vala-identifier">
    <xsl:param name="text"/>
    <xsl:choose>
      <xsl:when test="starts-with($text,'Gtk')">
        <func:result select="concat('Gtk.',valax:vala-identifier(substring-after($text,'Gtk')))"/>
      </xsl:when>
      <xsl:otherwise>
        <func:result select="valax:vala-identifier($text)"/>
      </xsl:otherwise>
    </xsl:choose>
  </func:function>

  <func:function name="valax:C-quote">
    <xsl:param name="text"/>
    <func:result select="str:replace($text,str:tokenize('\,&quot;',','),str:tokenize('\\,\&quot;',','))"/>
  </func:function>

  <func:function name="valax:vala-identifier">
    <xsl:param name="id"/>

	<xsl:variable name="prefix">
      <xsl:if test="substring($id,1,1) &gt;= '0' and substring($id,1,1) &lt;= '9'">
	    <xsl:text>_</xsl:text>
	  </xsl:if>
    </xsl:variable>
	
    <func:result select="concat($prefix,valax:_vala-identifier(normalize-space($id)))"/>
  </func:function>
  
  <func:function name="valax:_vala-identifier">
    <xsl:param name="id"/>
    <xsl:param name="previous"/>

    <xsl:choose>
	    <xsl:when test="$id=''">
	      <func:result select="''"/>
	    </xsl:when>
	    <xsl:when test="not(valax:identifier-char(substring($id,1,1)))">

      <xsl:choose>
  	      <xsl:when test="$previous='_'">
            <func:result select="valax:_vala-identifier(substring($id,2),'_')"/>
          </xsl:when>
          <xsl:otherwise>
            <func:result select="concat('_',valax:_vala-identifier(substring($id,2),'_'))"/>
          </xsl:otherwise>
        </xsl:choose>
        
      </xsl:when>
      <xsl:otherwise>
        <func:result select="concat(substring($id,1,1),valax:_vala-identifier(substring($id,2),''))"/>
      </xsl:otherwise>
    </xsl:choose>	
  </func:function>

  <xsl:template match="/">
	  <xsl:variable name="class" select="concat($class-prefix,valax:vala-identifier(//object/@id))"/>
		<xsl:variable name="class-count-name" select="concat($class,'_WIDGET_COUNT')" />
		<xsl:variable name="widget-count" select="count(//object[@id])"/>
		
		<xsl:if test="not($widget-count &gt; 0)">
		  <xsl:message terminate="yes">Error: Could not find any gtk objects.</xsl:message>
		</xsl:if>

	  <xsl:text>/* Auto generated by gen-vala-gtk-widget-bindings.xslt */&#xA;&#xA;
using GLib;
using Gtk;
    
public class </xsl:text><xsl:value-of select="valax:vala-identifier(//object/@id)"/><xsl:text> : Gtk.Object {
  construct {
	  this.xml = new Gtk.Builder ();
    this.xml.add_from_string(xmldef, (int)xmldef.size());
    this.widgets=new window_widgets();
    widget_connect();
  }
  private void widget_connect() {
    weak SList&lt;Gtk.Widget&gt; widgets = this.xml.get_objects();
    Gtk.Widget **sym;

    foreach (Gtk.Widget widget in widgets) {
      int c;

      for (c=0; widget_info[c].name != null; c++) {
        if (widget_info[c].name == widget.name) {
            Gtk.Widget **sym=&amp;(this.widgets.</xsl:text><xsl:value-of select="valax:vala-identifier(//object/@id)"/><xsl:text>) + widget_info[c].index;
            *sym=widget;
            break;
        }
      }
      if (widget_info[c].name == null) {
        stdout.printf ("Symbol not found: %s\n", widget.name);
      }
    }

  }

  [InstanceLast]
  protected void connect_signal (Gtk.Builder builder, GLib.Object object, string signal_name, string handler_name, GLib.Object? connect_objectt, GLib.ConnectFlags flags) {
    void* sym;

    if (!module.symbol (namespace + handler_name, out sym) &amp;&amp; !module.symbol (handler_name, out sym)) {
      stdout.printf ("Symbol not found: %s => %s\n", signal_name, handler_name);
    } else {
      GLib.Signal.connect(object, signal_name, (GLib.Callback) sym, this);
    }
  }

  protected void connect_signals(string namespace) {
    this.namespace=namespace;
    if (null!=(this.module = Module.open (null, ModuleFlags.BIND_LAZY))) {
      this.xml.connect_signals_full(connect_signal);
    }
  }

  protected string namespace;
  private Module module;
  protected class window_widgets {&#xA;</xsl:text>
    <xsl:for-each select="//object[@id]">
			<xsl:text>    protected </xsl:text>
      <xsl:value-of select="valax:glade-to-vala-identifier(@class)"/>
      <xsl:text> </xsl:text>
			<xsl:value-of select="valax:vala-identifier(@id)"/>
			<xsl:text>; /* </xsl:text>
      <xsl:value-of select="@class"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="@id"/>
      <xsl:text> */&#xA;</xsl:text>
    </xsl:for-each>
	  <xsl:text>
  }
  protected struct window_widget_names { 
    protected int index;
    protected string class;
    protected string name;
  }
  protected Gtk.Builder xml;
  protected window_widgets widgets;
  protected static const window_widget_names[] widget_info = {
    /* widget name list for runtime binding */&#xA;</xsl:text>
			<xsl:for-each select="//object[@id]">
			  <xsl:variable name="identifier" select="valax:vala-identifier(@id)"/>

				<xsl:call-template name="widget-info"/>
				
				<xsl:if test="normalize-space(@id) != $identifier">
				  <xsl:call-template name="widget-info">
					  <xsl:with-param name="id" select="$identifier"/>
					</xsl:call-template>
				</xsl:if>

				</xsl:for-each>
			<xsl:text>    {0, null, null}
  };

  private static const string xmldef="</xsl:text>
    <!-- now copy the xml as a constant -->
    <xsl:apply-templates/>
    <xsl:text>&quot;;&#xA;}&#xA;</xsl:text>
	</xsl:template>

	<xsl:template name="widget-info">
	  <xsl:param name="id" select="@id"/>
		<xsl:param name="class" select="@class"/>
		<xsl:param name="index" select="position() - 1"/>
		
		<xsl:text>    {</xsl:text>
		<xsl:value-of select="$index"/>
		<xsl:text>, &quot;</xsl:text>
		<xsl:value-of select="$class"/>
		<xsl:text>&quot;, &quot;</xsl:text>
		<xsl:value-of select="$id"/>
		<xsl:text>&quot;},&#xA;</xsl:text>
	</xsl:template>
  
  <!-- convert an xml node set into a C string of the xml, 
       very ROUGHLY with little respect for namespaces -->
  <xsl:template match="comment()">
    <xsl:text>&lt;!-- </xsl:text>
    <xsl:value-of select="valax:C-quote(.)"/>
    <xsl:text>--&gt;</xsl:text>
  </xsl:template>

  <!-- replace newline with close quote, newline, open quote -->
  <xsl:template match="text()">
    <xsl:if test="starts-with(.,$eol)">
<!--      <xsl:text>\n&quot;&#xA;&quot;</xsl:text> -->
      <xsl:text>\n</xsl:text>
    </xsl:if>
    <xsl:for-each select="str:split(.,$eol)">
      <xsl:value-of select="valax:C-quote(.)"/>
      <xsl:if test="not(position()=last()) or substring(.,string-length(.)-string-length($eol)+1)=$eol">
        <xsl:text>\n</xsl:text>
<!--        <xsl:text>\n&quot;&#xA;&quot;</xsl:text> -->
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="node()">
    <xsl:choose>
      <xsl:when test="comment()">
        <xsl:text>comment</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <!-- start node -->
        <xsl:text>&lt;</xsl:text>
        <xsl:value-of select="name()"/>
       <!-- write attributes -->
        <xsl:for-each select="@*">
          <xsl:text> </xsl:text>
          <xsl:value-of select="name()"/>
          <xsl:text>=\&quot;</xsl:text>
          <xsl:value-of select="valax:C-quote(.)"/>
          <xsl:text>\&quot;</xsl:text>
        </xsl:for-each>
        <xsl:choose>
          <xsl:when test="count(node()|text()|comment())=0">
            <xsl:text>/&gt;</xsl:text>
          </xsl:when>
          <xsl:otherwise>
            <xsl:text>&gt;</xsl:text>
            <xsl:apply-templates select="node()|text()|comment()"/>
            <xsl:text>&lt;/</xsl:text>
            <xsl:value-of select="name()"/>
            <xsl:text>&gt;</xsl:text>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:transform>